Function MdbToHtml(strSql) 'As String
Dim strTable
Dim intField 'As Integer
Dim db 'As Database
Dim dbeng 'As DAO.DBEngine
Dim rs 'As Recordset
Const dbReadOnly = 4 'DAO.RecordsetOptionEnum
Const dbOpenSnapshot = 4 'DAO.RecordsetTypeEnum
	Set dbeng = CreateObject("DAO.DBEngine.36")
	Set db = dbeng.OpenDatabase(FileNameLikeMine("mdb"), False, True)
	Set rs = db.OpenRecordset(strSql, dbOpenSnapshot, , dbReadOnly)
	If Not(rs.EOF And rs.BOF) Then
		rs.MoveLast
		rs.MoveFirst
		'First send out the column headers
		strTable = "<table border=1>" & vbCrLf & "<tr>" 
		For intField = 0 to rs.Fields.Count - 1
			strTable = strTable & "<th bgcolor=#CCCCCC><b>" & rs.Fields(intField).Name & "</b></th>"
		Next
		strTable = strTable & "</tr>" & vbCrLf
		'Now send out the table body
		Do until rs.EOF
			strTable = strTable & "<tr>"
			For intField = 0 to rs.Fields.Count - 1
				If IsNull(rs.Fields(intField).Value) Then
					strTable = strTable & "<td>&nbsp;</td>"
				Else
					If rs.Fields(intField).Value = "" Then
						strTable = strTable & "<td>&nbsp;</td>"
					Else
						strTable = strTable & "<td>" & rs.Fields(intField).Value & "</td>"
					End If
				End If
			Next
			strTable = strTable & "</tr>" & vbCrLf
			rs.MoveNext
		Loop
		strTable = strTable & "</table>"
		MdbToHtml = strTable
	Else
		MdbToHtml = ""
	End If
End Function